I've put together my first (currently untested) ASM source file. Please take a look at my code. There are some commented questions that describe my troubles:
TITLE Data Definitions (DataDefinitions.asm)
; This program contains data definitions for several data types.
; Each variable is initialized to a value that is consistent with
; its data type.
; Author: RedSkeleton007
; Date Last Modified: 06/26/2015
INCLUDE Irvine32.inc
;What's the characters for asm block comments?
;.data?
;byteValue BYTE ?
;sbyteValue SBYTE ?
;wordValue WORD ?
;swordValue SWORD ?
;sdwordValue SDWORD ?
;fwordValue FWORD ?
;qwordValue QWORD ?
;tbyteValue TBYTE ?
;real4Value REAL4 ?
;real8Value REAL8 ?
;real10Value REAL10 ?
;array WORD 5 DUP(?) ;5 values, uninitialized
.data
;ARRAY
List1 WORD 1,2,3,4,5
List2 SWORD -1,-2,-3,-4,-5
;BYTE
charVariable BYTE 'A'
strVariable BYTE "Green",0 ;5 chars = 5 bytes = 40 bits
numVariable BYTE 0
;SBYTE
sbyte_Var1 SBYTE -128 ;smallest possible signed byte
sbyte_Var2 SBYTE +127 ;largest possible signed byte
;WORD
word_Var1 WORD 65535 ;largest unsigned value
;SWORD
sword_Var1 SWORD -32768 ;smallest signed value
;DWORD
doubleWord DWORD 12345678h ;also can be written as: doubleWord DD 12345678h
;SDWORD
signedDblWord SDWORD -123456789h ;also can be written as: signedDblWord DD -123456789
;FWORD
fword_Var1 FWORD "";48 bits = 6 chars or digits
;QWORD
qword_Var1 QWORD 1234567812345678h
qword_Var2 QWORD "BigFatLazyDude99" ;string of 16 chars in length
qword_Var3 DQ "BigFatLazyDude69" ;string of 16 chars in length
;TBYTE
tbyteNegative TBYTE 800000000000001234h ;decimal value = -1234
tbytePositive TBYTE ? ;what would be the equivalent to the decimal value 1234?
;REAL4
realValue1 REAL4 -1.2
;REAL8
realValue2 REAL8 3.2E-260 ;WTF is this? Scientific notation? Does -260 mean it's signed?
;REAL10
realValue3 REAL10 4.6E+4096
printALL PROTO
main PROC
;call the printALL function to print out all initialized values:
INVOKE printALL
exit
main ENDP
;define the printALL function:
printALL
;Print: charVariable, strVariable, numVariable,...
END
Thanks :biggrin:
where is the code for "printAll" ?
or - at least tell us what it's supposed to do
here is a template that may be used with the Irvine32 library
notice that you may have to change the paths for INC's and LIB's
also notice that i have added CaseMap:None
that means that symbol names are case sensitive
;###############################################################################################
INCLUDE \Masm32\Irvine\Irvine32.inc ;adds SmallWin.inc, VirtualKeys.inc
OPTION CaseMap:None
INCLUDE \Masm32\Irvine\floatio.inc
INCLUDE \Masm32\Irvine\GraphWin.inc
INCLUDE \Masm32\Irvine\macros.inc
INCLUDELIB \Masm32\Irvine\kernel32.lib
INCLUDELIB \Masm32\Irvine\user32.lib
INCLUDELIB \Masm32\Irvine\Irvine32.lib
;###############################################################################################
.DATA
szMessage db 'Hello World',13,10,0
;***********************************************************************************************
.DATA?
;###############################################################################################
.CODE
;***********************************************************************************************
main PROC
mov edx,offset szMessage
call WriteString
call WaitMsg
INVOKE ExitProcess,0
main ENDP
;###############################################################################################
END main
Quote from: dedndave on June 27, 2015, 07:41:08 AM
where is the code for "printAll" ?
or - at least tell us what it's supposed to do
In my code, I have variables initialized to values under the .data directive. For each of them, I simply want to print out the values they're initialized to. I suppose I could print all of them out one by one in the main PROC. What do you think?
You should put the "printall" function in a separate proc as you indicated. Then, simply write a separate print statement for each datum. You do know how to print one variable, say, a dword?
BTW I'd never heard of an "fword" before. U learn something new every day ... I wonder what format specifier it uses? Probably have to put it in a qword and print that. You have to do similar to print real4 variable with C-style print: put it in a real8. real10 is also difficult - well you can cross those bridges when you get there
what i meant was - what are the specific details of the printAll routine?
but - let's be more generic....
let's say you want a PROC that you can INVOKE.....
near the beginning of the program, you need a PROTOtype
it tells masm how many arguments there are, and the arg sizes
for 32-bit code, the sizes are nearly always DWORD (to keep the stack 4-aligned)
usually, PROTO's go right after the INCLUDE's
i often put them in a project INC file - and add it last
but, we're going to demonstrate a single PROTO
MyFunc PROTO :DWORD,:DWORD,:DWORD
next, in the body of the code, the PROC may be called using INVOKE....
INVOKE MyFunc,Arg1,Arg2,Arg3
the ArgN values may be registers, memory locations (data symbol names), immediate values, or even referenced addresses
INVOKE MyFunc,1,dwMyVariable,eax
now, for the PROC....
following windows ABI, we will preserve EBX, ESI, EDI
EBP is also preserved, but the assembler handles that, as well as the stack frame
MyFunc PROC USES EBX ESI EDI Arg01:DWORD,Arg02:DWORD,Arg03:DWORD
LOCAL dwLocalDword :DWORD ;create a local dword on the stack
LOCAL abArray[256] :BYTE ;create a local array of 256 bytes on the stack
mov eax,Arg01 ;for example
;
;
;
mov eax,dwLocalDword ;return result or status in EAX
ret
MyFunc ENDP
dedndave,
since printALL has no arguments you can simply call it. If u want to invoke it the proto statement is simply as shown by OP. And if you look at his prog he exits after printALL so no need to preserve registers.
FWORD exists, but 1. its use is extremely limited (https://courses.engr.illinois.edu/ece390/books/artofasm/CH05/CH05-1.html#HEADING1-163), 2. contrary to your expectations, there are five letters, not four, in FWORD 8)
@jj2007,
I thought of the "fword" joke also but refrained from stooping so low :)
Anyway I think OP just needs to know how to do C-style printing with printf, but maybe he wants to know how to invoke ... waiting for further clarification
Quote from: rrr314159 on June 28, 2015, 01:44:18 AM... but refrained from stooping so low :)
Coward :P
If Red has trouble finding a procedure to print out the Real10 format, have a look at the Fpulib if you can use it. You could even use it for ALL your floating point values.
Quote from: RedSkeleton007 on June 27, 2015, 06:54:38 AM
;What's the characters for asm block comments?
COMMENT ~
this is commented out
so is this
and this
~
;anything from this point is not...
The first character after COMMENT marks the start and end -- it can be anything -- in this case ~.
QuotestrVariable BYTE "Green",0 ;5 chars = 5 bytes = 40 bits
5 chars + terminating null = 6 bytes
Quoteqword_Var2 QWORD "BigFatLazyDude99" ;string of 16 chars in length
qword_Var3 DQ "BigFatLazyDude69" ;string of 16 chars in length
Be careful here - the characters are not stored the same way as if you had used "BYTE".
QuotetbyteNegative TBYTE 800000000000001234h ;decimal value = -1234
tbytePositive TBYTE ? ;what would be the equivalent to the decimal value 1234?
1234 = 4D2h
-1234 = FFFFFFFFFFFFFFFFFB2Eh ;(see two's-complement for representation of negative numbers)
QuoterealValue2 REAL8 3.2E-260 ;WTF is this? Scientific notation? Does -260 mean it's signed?
realValue3 REAL10 4.6E+4096
3.2E-260 = 3.2 x 10
-260 = 0.0000000000000.............................00000000032
4.6E+4096 = 4.6 x 10
4096 = 46000000000000000........................000000000000000
(additional zeroes omitted)
Gentlemen, lets start over :bgrin:
Lets just print out some simple string values, so that I can learn what MASM syntax is equivalent to "cout << stringValue << endl" in C++.
Here's my untested code:
; This program defines symbolic constants for all seven days
; of the week, then demonstrates them by outputting them to
; the screen.
.386
.model flat,stdcall
.stack 4096
ExitProcess proto,dwExitCode:dword
.data
numDays BYTE "There are 7 days in a week. They are:"
Mon BYTE "Monday",0
Tues BYTE "Tuesday",0
Wed BYTE "Wednesday",0
Thurs BYTE "Thursday",0
Fri BYTE "Friday",0
Sat BYTE "Saturday",0
Sun BYTE "Sunday",0
.code
main proc
; What's the MASM syntax for outputting values stored in variables?
; output Mon,0dh,0ah,0
; output Tuesday,0dh,0ah,0
; output Wednesday,0dh,0ah,0
; output Thurs,0dh,0ah,0
; output Fri,0dh,0ah,0
; output Sat,0dh,0ah,0
; output Sun
invoke ExitProcess,0
main endp
end main
For my intentions, the C++ equivalent of what I'm trying to accomplish here is:
#include <cstdlib>
#include <iostream>
#include <fstream>
#include <array>
#include <string>
using namespace std;
int main()
{
string Mon = "Monday";
string Tues = "Tuesday";
string Wed = "Wednesday";
string Thurs = "Thursday";
string Fri = "Friday";
string Sat = "Saturday";
string Sun = "Sunday";
cout << "There are 7 days in a week. They are: \n";
cout << Mon << endl;
cout << Tues << endl;
cout << Wed << endl;
cout << Thurs << endl;
cout << Fri << endl;
cout << Sat << endl;
cout << Sun << endl;
system("pause");
return 0;
}
Also, why is the BYTE intrinsic data type used so often?
I would adopt a simple way to use the streams :
include Streams.inc
_iobuf STRUCT
_ptr DWORD ?
_cnt DWORD ?
_base DWORD ?
_flag DWORD ?
_file DWORD ?
_charbuf DWORD ?
_bufsiz DWORD ?
_tmpfname DWORD ?
_iobuf ENDS
FILE TYPEDEF _iobuf
.data
msg db 'stdout = %X',0
.data?
stdout dd ?
stdin dd ?
stderr dd ?
.code
start:
call crt___p__iob
mov stdin,eax ; #define stdin (&__iob_func()[0])
mov ecx,SIZEOF(FILE)
add eax,ecx
mov stdout,eax ; #define stdout (&__iob_func()[1])
add eax,ecx
mov stderr,eax ; #define stderr (&__iob_func()[2])
invoke crt_fprintf,stdout,ADDR msg,stdout
invoke ExitProcess,0
END start
DAYS_OF_WEEK STRUCT
lpSun LPSTR ?
lpMon LPSTR ?
lpTue LPSTR ?
lpWed LPSTR ?
lpThu LPSTR ?
lpFri LPSTR ?
lpSat LPSTR ?
DAYS_OF_WEEK ENDS
.DATA
ALIGN 4
dow DAYS_OF_WEEK <szSun,szMon,szTue,szWed,szThu,szFri,szSat>
szSun BYTE "Sunday",0
szMon BYTE "Monday",0
szTue BYTE "Tuesday",0
szWed BYTE "Wednesday",0
szThu BYTE "Thursday",0
szFri BYTE "Friday",0
szSat BYTE "Saturday",0
now, you can calculate the offset into the "dow" structure using (4*X), where X = 0 to 6
;EAX = 0 to 6
mov edx,dow[4*eax] ;EDX = address
print edx
you can certainly do that in a single line, too
print dow[4*eax]
if you just want to print a string....
print offset szMon
the print macro wants an address
One more (https://msdn.microsoft.com/library/az4se3k1%28v=vs.100%29.aspx) :biggrin:
include \masm32\MasmBasic\MasmBasic.inc ; download (http://masm32.com/board/index.php?topic=94.0)
Init
For_ ecx=0 To 6
PrintLine fDate$(ecx, "dddd")
Next
Inkey "(wow, that was tough)"
EndOfCode
Output:
Monday
Tuesday
Wednesday
Thursday
Friday
Saturday
Sunday
Will work only today 8)
Quote from: dedndave on January 25, 2016, 09:17:20 AM
DAYS_OF_WEEK STRUCT
lpSun LPSTR ? ;what is does lp and LP do?
lpMon LPSTR ?
lpTue LPSTR ?
lpWed LPSTR ?
lpThu LPSTR ?
lpFri LPSTR ?
lpSat LPSTR ?
DAYS_OF_WEEK ENDS
.DATA
ALIGN 4 ;what is being aligned by 4 spaces?
dow DAYS_OF_WEEK <szSun,szMon,szTue,szWed,szThu,szFri,szSat> ;what is up with the sz?
szSun BYTE "Sunday",0
szMon BYTE "Monday",0
szTue BYTE "Tuesday",0
szWed BYTE "Wednesday",0
szThu BYTE "Thursday",0
szFri BYTE "Friday",0
szSat BYTE "Saturday",0
My questions for you are commented in your code above.
Quote from: dedndave on January 25, 2016, 09:17:20 AM
now, you can calculate the offset into the "dow" structure using (4*X), where X = 0 to 6
What are you even talking about? Is dow a reserved word? Remember, I'm only finishing chapter 3, so keep it as simple as possible please.
lpSun LPSTR ? ;what is does lp and LP do?
lpSun is just a symbol name, using "Hungarian Notation"
it means that lpSun is a "Long Pointer", which you can tell just by looking at the name
this notation is often used on the MSDN site - so, it's nice to be familiar
(i could have also used lpszSun, meaning it's a long pointer to a zero-terminated string)
https://en.wikipedia.org/wiki/Hungarian_notation (https://en.wikipedia.org/wiki/Hungarian_notation)
LPSTR is a type - it is defined in windows.inc as
LPSTR TYPEDEF DWORD
meaning it is DWORD size - it stands for "Long Pointer to a STRing"
.DATA
ALIGN 4 ;what is being aligned by 4 spaces?
the "dow" structure is aligned to an address that is evenly divisable by 4
accessing dword-sized data is faster when it is 4-aligned
"dow" is defined in the .DATA section as
dow DAYS_OF_WEEK <szSun,szMon,szTue,szWed,szThu,szFri,szSat> ;what is up with the sz?
and finally, "sz" is again Hungarian Notation, meaning "String, Zero-terminated"
here's an example of an MSDN page...
https://msdn.microsoft.com/en-us/library/windows/desktop/ms684183%28v=vs.85%29.aspx (https://msdn.microsoft.com/en-us/library/windows/desktop/ms684183%28v=vs.85%29.aspx)
the C prototype
DWORD WINAPI LoadModule(
_In_ LPCSTR lpModuleName,
_In_ LPVOID lpParameterBlock
);
DWORD WINAPI = returns a DWORD (in EAX), windows API function
_In_ = it's an input argument
LPCSTR = long pointer to a constant string
LPVOID = long pointer to an undescribed type
lpModuleName and lpParameterBlock are symbol names that use Hungarian Notation
Quote from: dedndave on January 25, 2016, 09:17:20 AM
DAYS_OF_WEEK STRUCT
lpSun LPSTR ?
lpMon LPSTR ?
lpTue LPSTR ?
lpWed LPSTR ?
lpThu LPSTR ?
lpFri LPSTR ?
lpSat LPSTR ?
DAYS_OF_WEEK ENDS
.DATA
ALIGN 4
dow DAYS_OF_WEEK <szSun,szMon,szTue,szWed,szThu,szFri,szSat>
szSun BYTE "Sunday",0
szMon BYTE "Monday",0
szTue BYTE "Tuesday",0
szWed BYTE "Wednesday",0
szThu BYTE "Thursday",0
szFri BYTE "Friday",0
szSat BYTE "Saturday",0
now, you can calculate the offset into the "dow" structure using (4*X), where X = 0 to 6
;EAX = 0 to 6
mov edx,dow[4*eax] ;EDX = address
print edx
you can certainly do that in a single line, too
print dow[4*eax]
if you just want to print a string....
print offset szMon
the print macro wants an address
I tried it your way dedndave, but I got some errors that I'm not sure how to fix:
; This program defines symbolic constants for all seven days
; of the week, then demonstrates them by outputting them to
; the screen.
.386
.model flat,stdcall
.stack 4096
ExitProcess proto,dwExitCode:dword
DAYS_OF_WEEK STRUCT
lpSun LPSTR ? ;error: initializer magnitude too large for specified size
lpMon LPSTR ?
lpTue LPSTR ?
lpWed LPSTR ?
lpThu LPSTR ?
lpFri LPSTR ?
lpSat LPSTR ?
DAYS_OF_WEEK ENDS
.data
;ALIGN 4
dow DAYS_OF_WEEK <szSun,szMon,szTue,szWed,szThu,szFri,szSat> ;error: structure cannot be instanced
szSun BYTE "Sunday",0
szMon BYTE "Monday",0
szTue BYTE "Tuesday",0
szWed BYTE "Wednesday",0
szThu BYTE "Thursday",0
szFri BYTE "Friday",0
szSat BYTE "Saturday",0
.code
main proc
; What's the MASM syntax for outputting values stored in variables?
mov edx,dow[4*eax] ;EDX = address
print edx ;error: undefined symbol
invoke ExitProcess,0
main endp
end main
The structure cannot be instanced error is due to the previous error relating to LPSTR ? ;error: initializer magnitude too large for specified size.
Im guessing you need to include windows.inc in your source file so it knows what LPSTR is. Try this:
.386
.model flat,stdcall
.stack 4096
include windows.inc
or if that doesnt work, you can always change the LPSTR references to DWORD instead, like:
DAYS_OF_WEEK STRUCT
lpSun DWORD ? ;error: initializer magnitude too large for specified size
lpMon DWORD ?
lpTue DWORD ?
lpWed DWORD ?
lpThu DWORD ?
lpFri DWORD ?
lpSat DWORD ?
DAYS_OF_WEEK ENDS
windows.inc includes the typedef for the LPSTR as (basically seen as the same thing to the assembler, more useful for us humans to understand its a pointer to a string):
LPSTR typedef DWORD
windows.inc is correct
and - you don't need a .stack statement with a flat model
Quote from: fearless on January 26, 2016, 12:09:49 PM
windows.inc includes the typedef for the LPSTR as (basically seen as the same thing to the assembler, more useful for us humans to understand its a pointer to a string):
LPSTR typedef DWORD
We're getting closer ;) Please see the comments in my code:
; This program defines symbolic constants for all seven days
; of the week, then demonstrates them by outputting them to
; the screen.
.386
.model flat,stdcall
.stack 4096
ExitProcess proto,dwExitCode:dword ;what is this line doing?
DAYS_OF_WEEK STRUCT
lpSun DWORD ?
lpMon DWORD ?
lpTue DWORD ?
lpWed DWORD ?
lpThu DWORD ?
lpFri DWORD ?
lpSat DWORD ?
DAYS_OF_WEEK ENDS
.data
;ALIGN 4
dow DAYS_OF_WEEK <szSun,szMon,szTue,szWed,szThu,szFri,szSat>
szSun BYTE "Sunday",0
szMon BYTE "Monday",0
szTue BYTE "Tuesday",0
szWed BYTE "Wednesday",0
szThu BYTE "Thursday",0
szFri BYTE "Friday",0
szSat BYTE "Saturday",0
.code
main proc
; What's the MASM syntax for outputting values stored in variables?
mov edx,dow[4*eax] ;error: instruction operands must be the same size
print edx ;error: initializer magnitude too large for specified size
invoke ExitProcess,0
main endp
end main
Also, why are we putting the STRUCT before the .data directive portion of the code?
remove the .stack statement
if operand size is an issue, use a size override
mov edx,dword ptr dow.[4*eax]
the error on print doesn't make sense
it could be because of .386, rather than .486 or .586
.386 does not allow some "newer" addressing modes, and some instructions
when we build, even the simplest of programs, we include several INC files and includelib several LIB files
(they take care of most of the API prototypes, like ExitProcess)
to avoid all that typing, we generally place one line at the beginning
INCLUDE \masm32\include\masm32rt.inc
it also takes care of the processor, model, and casemap
it's a plain text file (you can open it with NotePad)
have a look at it to see what it adds to the program source
and - structure definitions do not create any code - they merely define a new type, in a way
they do not need to be in an open data/code section
give this one a try
;###############################################################################################
INCLUDE \Masm32\Include\Masm32rt.inc
.586
;###############################################################################################
DAYS_OF_WEEK STRUCT
lpSun DWORD ?
lpMon DWORD ?
lpTue DWORD ?
lpWed DWORD ?
lpThu DWORD ?
lpFri DWORD ?
lpSat DWORD ?
DAYS_OF_WEEK ENDS
;###############################################################################################
.DATA
ALIGN 4
dow DAYS_OF_WEEK <szSun,szMon,szTue,szWed,szThu,szFri,szSat>
szSun BYTE "Sunday",0
szMon BYTE "Monday",0
szTue BYTE "Tuesday",0
szWed BYTE "Wednesday",0
szThu BYTE "Thursday",0
szFri BYTE "Friday",0
szSat BYTE "Saturday",0
;***********************************************************************************************
; .DATA?
;###############################################################################################
.CODE
;***********************************************************************************************
main PROC
mov ebx,7
loop00: mov eax,7
sub eax,ebx
print dow.lpSun[4*eax],13,10
dec ebx
jnz loop00
inkey
exit
main ENDP
;###############################################################################################
END main
EDIT: changed it to
print dow.lpSun[4*eax],13,10
Quote from: dedndave on January 26, 2016, 10:12:02 PM
when we build, even the simplest of programs, we include several INC files and includelib several LIB files
(they take care of most of the API prototypes, like ExitProcess)
to avoid all that typing, we generally place one line at the beginning
INCLUDE \masm32\include\masm32rt.inc
It should be noted that I'm using Kip Irvine's text book:
http://kipirvine.com/asm/ (http://kipirvine.com/asm/)
and its resources. I cannot predict what might happen if I tried including both libraries and source into my code. And I'm strongly reluctant to switching to the MASM32 compiler used by the members on these forums, because later on in Irvine's text book, he uses C++ code with inline assembly language in the same source code files. And for someone like me who's more familiar with C++, it will very likely make it easier to understand what's going on with the MASM syntax. Plus, I payed over $500 for Visual Studio Professional 2013!
Also, right now, I'm just trying to accomplish one of the end-of-chapter programming exercises, worded exactly as:
"Write a program that defines symbolic constants for all seven days of the week. Create an array variable that uses the symbols as initializers."
Loops are not introduced until the next chapter. I have not encountered Structs in the book yet. The reason I'm trying so hard to print them out is JUST SO I CAN TEST THE DAMNED THINGS! But since this isn't an easy-peesy Java or C++ Hello World App, is there a better, more simpler way to test MASM assembly code than printing out values?
i've been working on an Irvine32.lib and inc that are compatible with masm32
here are my notes...
Quote1) In the Irvine32 library, the "OPTION CaseMap:None" directive is commented out as optional.
Per Microsoft API documentation, case sensitivity should be observed.
The Masm32 library is also designed for case sensitive symbols.
2) The POINT structure was defined with members named upper-case "X" and "Y".
Per Microsoft documentation, these were renamed to lower-case "x" and "y".
3) "GetTextColor" and "SetTextColor" are functions defined in the Irvine32 library.
They are used to retrieve and set console-mode text color.
However, pre-existing Microsoft API functions (used for GUI apps) are defined in Gdi32.dll.
To allow them to co-exist, we use the names "GetConTextColor" and "SetConTextColor".
4) "MsgBox" is a PROC defined in Irvine32, used in a few Irvine32 example programs.
"MsgBox" is a powerful MACRO defined in Masm32, used in many existing programs.
The Irvine32 PROC name is changed to "MsgBoxOk".
5) "exit" is a TEXTEQUate (pseudo-macro) defined in Irvine32.
"exit" is a MACRO defined in Masm32 that allows an optional return code argument.
The Masm32 macro will perform the same function if no arguments are specified.
Conditional assembly is used to avoid redefinition in Irvine32.
6) In the Irvine32 SmallWindows.inc file, SetConsoleCursorPosition, SetConsoleScreenBufferSize,
WriteConsoleOutputCharacter, and WriteConsoleOutputAttribute are all PROTOtyped with COORD arguments.
While this is technically correct, it does not allow the use of a register in place of a COORD structure.
A COORD structure has 2 WORD members, that may be replaced with any DWORD sized operand, if PROTOtyped as such.
The Masm32 library PROTOtypes these functions with DWORD arguments in place of COORD structures.
7) The SetConsoleTextAttribute function is PROTOtyped with a WORD argument. Again, this is technically correct,
per MSDN documentation. However, arguments are passed on the stack and the stack should always retain DWORD
alignment in Win32 programming. The Masm32 library has this function PROTOtyped with a DWORD argument.
8- Irvine32 example programs may be modified to be compatible by making a few name changes.
Fortunately, most Irvine32 examples do not use these symbols:
MsgBox -> MsgBoxOk
GetTextColor -> GetConTextColor
SetTextColor -> SetConTextColor
POINT.X,Y -> POINT.x,y
Function calls mentioned in 6) and 7), above, may require some modification to match argument size and type.
Also, all symbol names are now case sensitive. Some modification may be required to match case.
As you have Visual Studio, you can watch registers in there ;)
.386
.model flat,stdcall
ExitProcess proto dwExitCode:dword
printf proto C :dword, :vararg
includelib msvcrt.lib
DAYS_OF_WEEK STRUCT
lpSun DWORD ?
lpMon DWORD ?
lpTue DWORD ?
lpWed DWORD ?
lpThu DWORD ?
lpFri DWORD ?
lpSat DWORD ?
DAYS_OF_WEEK ENDS
.data
dow DAYS_OF_WEEK <szSun,szMon,szTue,szWed,szThu,szFri,szSat>
szSun BYTE "Sunday",0
szMon BYTE "Monday",0
szTue BYTE "Tuesday",0
szWed BYTE "Wednesday",0
szThu BYTE "Thursday",0
szFri BYTE "Friday",0
szSat BYTE "Saturday",0
szCrLf db 13,10,0
.code
main proc
mov esi, offset dow ;[0] ; point to pointer array
mov ebx, 7 ; counter
@@:
mov edi, dword ptr esi ; point to string
invoke printf, edi ; print string
invoke printf, addr szCrLf ; linefeed
add esi, 4 ; move to next dword pointer
dec ebx ; count down
jnz @B ; until zero
invoke ExitProcess,0
main endp
end mainEDIT:
Beware: use msvcrt.lib from masm32 package, not those sad msvc versions for cpp :(
Quote from: dedndave on January 26, 2016, 10:23:37 PM
give this one a try
;##################################################
INCLUDE \Masm32\Include\Masm32rt.inc
.586
;#####################################################
DAYS_OF_WEEK STRUCT
lpSun DWORD ?
lpMon DWORD ?
lpTue DWORD ?
lpWed DWORD ?
lpThu DWORD ?
lpFri DWORD ?
lpSat DWORD ?
DAYS_OF_WEEK ENDS
;##################################################
.DATA
ALIGN 4
dow DAYS_OF_WEEK <szSun,szMon,szTue,szWed,szThu,szFri,szSat>
szSun BYTE "Sunday",0
szMon BYTE "Monday",0
szTue BYTE "Tuesday",0
szWed BYTE "Wednesday",0
szThu BYTE "Thursday",0
szFri BYTE "Friday",0
szSat BYTE "Saturday",0
;*******************************************************************
; .DATA?
;######################################################
.CODE
;******************************************************************
main PROC
mov ebx,7
loop00: mov eax,7
sub eax,ebx
print dow.lpSun[4*eax],13,10
dec ebx
jnz loop00
inkey
exit
main ENDP
;#################################################
END main
I tried running this version of dedndave's code attempts in the MASM32 Application (apparently, I have already installed it before, and forgot about it). However, when I try to run an .asm file, a copy of that .asm file automatically opens up in Visual Studio as a standalone text file, along with two other windows (see attached picture). I recon it's not supposed to do that? How do I get Visual Studio to shut up and mind it's own business?
I can't seem to find the MASM32 Application manual anywhere in the MASM32 folder either. Where is it? My gut tells me that it would be easier for me to learn MASM (and easier for you guys to keep helping me) if I just use MASM32 instead of Visual Studio to learn MASM). Is that a good attitude to have, or should I stick with Irvine and Visual Studio? If MASM32 is the better choice, I have two little favors to ask:
1.) A template for Irvine's example programs looks like this:
; Program template
.386
.model flat,stdcall
.stack 4096
ExitProcess proto,dwExitCode:dword
.data
; declare variables here
.code
main proc
; write your code here
invoke ExitProcess,0
main endp
end main
Can you edit that code into what an MASM32 template is supposed to have?
2.)Make me a simple .asm file that, when it runs, will output "Hello World"
Thanks in advance.
Simple console "Hello World" is integrated into QEDITOR:
Menu Code -> Fast insert console template -> save it in right place (inside masm32 folder) -> Project -> Console build -> Project -> Run
let's start with visual studio opening asm files
i think you are refering to "File Associations" (a good google term - you can add "windows")
you should be able to right-click on an asm file, then "Open With"
(if that doesn't work, try shft-right-click)
when you do that, you will be given a choice to select from programs
and, when you do that, there is a little check box at the bottom of the dialog if you wish to change it
i hate to give advice to change a file association, because it may cause problems later on
but - right-clicking will at least allow you to select a different program
the irvine32 library include files have a small issue to be aware of
when you include the file, "Irvine32.inc", it includes a couple other INC files (SmallWin.inc, VirtualKeys.inc)
now, i am not sure about the details of how masm works - it seems to find these additional files for me
but, there is a potential problem with paths
at any rate - be aware that you may have to move things around or change paths, etc
also, i mentioned earlier that the CaseMap:None option is commented out
i prefer case sensitive symbol names, so i add it to my source
(less than ideal - probably better to modify Irvine32.inc and un-comment the OPTION line)
that having been said...
i created a folder in the root and copied all the irvine files in there...
;###############################################################################################
INCLUDE \Irvine\Irvine32.inc ;adds SmallWin.inc, VirtualKeys.inc
OPTION CaseMap:None
INCLUDE \Irvine\floatio.inc
INCLUDE \Irvine\GraphWin.inc
INCLUDE \Irvine\macros.inc
INCLUDELIB \Irvine\kernel32.lib
INCLUDELIB \Irvine\user32.lib
INCLUDELIB \Irvine\Irvine32.lib
;###############################################################################################
.DATA
szMessage db 'Hello World',13,10,0
;***********************************************************************************************
.DATA?
;###############################################################################################
.CODE
;***********************************************************************************************
main PROC
mov edx,offset szMessage
call WriteString
call WaitMsg
INVOKE ExitProcess,0
main ENDP
;###############################################################################################
END main
Quote from: dedndave on February 03, 2016, 12:25:49 AM
that having been said...
i created a folder in the root and copied all the irvine files in there...
So in other words, you figured out how to get MASM programs that use the irvine files to compile in the MASM32 Editor?
If so, do we not need this anymore:
INCLUDE \Masm32\Include\Masm32rt.inc
that line of code is for the Masm32 library package - Irvine's package is not 100% compatible
as for using QEditor, i don't see any reason you can't use the editor
but, the build menu options are for use with the Masm32 package
they execute batch files, and i think you can add menu items - so, you could add Irvine selections i think
i don't use QEditor - i use NotePad and NotePad++
and, i generally use my own batch files to build with
... if you have visual studio installed, it may set some of the environment variables that masm and link recognize
if that's the case, you may have to find work-arounds to add to your batch files
for example, you might use the SETLOCAL batch command to temporarily alter specific variables
or, there are command-line switches to override them
https://msdn.microsoft.com/en-us/library/s0ksfwcf.aspx (https://msdn.microsoft.com/en-us/library/s0ksfwcf.aspx)
https://msdn.microsoft.com/en-us/library/hx5b050y.aspx (https://msdn.microsoft.com/en-us/library/hx5b050y.aspx)
https://msdn.microsoft.com/en-us/library/6y6t9esh.aspx (https://msdn.microsoft.com/en-us/library/6y6t9esh.aspx)
command-line switches may vary from version to version
you can type
>ml /help
or
>ml /?
to get a list - same for link