CreateThread/TerminateThread API

[hesho28]

Hello,

I want an example of using CreateThread/TerminateThread APIs in masm32.

Thanks

[qWord]

TerminateThread is a function that does not appear in well written programs, because threads terminate themselves by calling ExitThread or returning from the thread-function (see also msdn)

Code Select Expand

include \masm32\include\masm32rt.inc
.code
thread proc param:PVOID
   
    fnc crt_printf,"param = 0x%X\n",param
   
    invoke ExitThread,0
thread endp

main proc
LOCAL hThread:DWORD
LOCAL dwTID:DWORD
   
    invoke CreateThread,0,0,thread,0BADF00Dh,0,ADDR dwTID
    mov hThread,eax
   
    ;...
   
    invoke WaitForSingleObject,hThread,INFINITE
    invoke CloseHandle,hThread
    print "fin",13,10
    inkey
   
    exit
main endp
end main

BTW: did you take a look in to the examples-folder?

[dedndave]

also - don't use parameters in the PROC line, or LOCAL's

Code Select Expand

        .XCREF
        .NoList
        INCLUDE    \Masm32\Include\Masm32rt.inc
        .List

;###############################################################################################

fnThread PROTO

;###############################################################################################

;        .DATA

;***********************************************************************************************

        .DATA?

hStdOut HANDLE ?

;###############################################################################################

        .CODE

;***********************************************************************************************

_main   PROC

        INVOKE  GetStdHandle,STD_OUTPUT_HANDLE
        mov     hStdOut,eax
        mov     edi,15

loop00: mov     eax,'P'
        sub     eax,edi
        INVOKE  CreateThread,0,0,fnThread,eax,0,0
        dec     edi
        jnz     loop00

        INVOKE  Sleep,250
        print   chr$(13,10)
        inkey
        INVOKE  ExitProcess,0

_main   ENDP

;***********************************************************************************************

fnThread PROC

    xor     eax,eax
    lea     edx,[esp+4]
    push    eax
    mov     ecx,esp
    INVOKE  WriteFile,hStdOut,edx,1,ecx,eax
    pop     ecx
    INVOKE  ExitThread,0

fnThread ENDP

;###############################################################################################

        END     _main

[qWord]

dave,
we had already had that discussion: the correct function has one parameter and can of course  use local variables.

DWORD WINAPI ThreadProc( _In_  LPVOID lpParameter);

[dedndave]

yah - but, i wasn't going to let you be the winner - lol
there is one parm passed, but the stack doesn't get balanced by a RET (unless you use RET)
if you want to use a stack-frame, make it yourself

[qWord]

there is one parm passed, but the stack doesn't get balanced by a RET (unless you use RET)

Sorry, I can't follow you.

[dedndave]

Code Select Expand

fnThread PROC Parm:DWORD
;
;
;
    INVOKE  ExitThread,0

fnThread ENDP
generates

Code Select Expand

fnThread PROC

    push    ebp
    mov     ebp,esp
;
;
;
    INVOKE  ExitThread,0

fnThread ENDP
the stack frame is created, but not balanced

the question is, does ExitThread really release the stack space (including previous operating system versions)

[qWord]

and what is the problem with that? The stack-memory will be release when the thread-object is destroyed, regardless what ESP points to.
Also, the MSDN is clear about ExitThread: "ExitThread is the preferred method of exiting a thread in C code"

[qWord]

the question is, does ExitThread really release the stack space (including previous operating system versions)

it does:

Code Select Expand


When this function is called (either explicitly or by returning from a thread procedure), the current thread's stack is deallocated, all pending I/O initiated by the thread is canceled, and the thread terminates. The entry-point function of all attached dynamic-link libraries (DLLs) is invoked with a value indicating that the thread is detaching from the DLL.

[jj2007]

The stack-memory will be release when the thread-object is destroyed, regardless what ESP points to.
Also, the MSDN is clear about ExitThread: "ExitThread is the preferred method of exiting a thread in C code"

An interesting question is whether correctly exiting with ret leaves something behind, i.e. what happens if an app creates a Million threads.

[TWell]

An interesting question is whether correctly exiting with ret leaves something behind, i.e. what happens if an app creates a Million threads.

Code Select Expand

ExitThread:
->RtlExitUserThread
  ->NtTerminateThread

ret:
->BaseThreadInitThunk
  ->RtlExitUserThread
    ->NtTerminateThread


[jj2007]

Code Select Expand

ExitThread:
->RtlExitUserThread
  ->NtTerminateThread

ret:
->BaseThreadInitThunk
  ->RtlExitUserThread
    ->NtTerminateThread


Makes sense, thanks. Probably their formula "the preferred method of exiting a thread in C code" means Microsoft doesn't believe C compilers can handle a retn n correctly ;-)

[dedndave]

it's been some time since i have read through the create/destroy thread documentation
but, i remember one thing that wasn't mentioned throughout most of it
then, it popped up in one or two places - to leave the reader in a mystery zone - lol
that was, closing the thread handle
to date, i have used CreateThread and ExitThread without any further coding
and, i've had what seems to be good success
but, i am still not sure if i should close the thread handle after it terminates

as for the stack, i was told by an experienced programmer that it could create memory leaks
it may well be that it was a windows 3.1 issue, that lingered into his current experience